______________________________________________________________________________
Modems:  Why does my Mac drop my connection during file transfers?


Adam Engst, noted author and halcyon subscriber, says:

For those who are getting cut off randomly using a Mac, check to see if you
have &D2 in your init string. That tells the modem to hangup when DTR drops
on the modem, which usually only happens when you try to disconnect.  However,
due to the way Macs handle serial ports and cables and the like, in certain
high-volume situations, DTR might drop for a short time to allow the Mac to
catch up with the data stream.  If you have &D2 in your init string, that
would then hang up the modem.  Needless to say, this would probably happen
mostly on long transfers.

If you remove &D2 from your init string, you may have to use a dialing script
to get your modem to hangup properly when you click the Disconnect button in
InterSLIP.  Here's what I use (it also redials):

cheers ... -Adam


To install this dialing script, copy it to a TEXT file (make sure
to save as text if you're using something like Word), and save it
in the Dialing Scripts folder inside your InterSLIP folder, which
in turn lives inside your Preferences folder. Launch InterSLIP, and
select the new dialing script from the Dialing pop-up menu in the
InterSLIP configuration window.


! Original script by Fred Morris
! Modifications and comments by Adam C. Engst
! 21-Feb-94 = Added redial feature (ACE)

@originate
! Initialize mode from string in InterSLIP configuration
note "Initializing modem"
write "^4\13"
pause 20
! Dial modem from number in InterSLIP configuration
note "Dialing ^1"
write "atdt^1\13"
! Check only for BUSY or CONNECT, then redial or connect
matchstr 1 10 "BUSY"
matchstr 2 20 "CONNECT"
matchread 500

@label 10
! The line is busy, so let's redial the modem indefinitely
! This will also redial after the (matchread 500) timeout if you get
endless rings
note "Line busy, redialing ^1"
! First hang up and reinitialize modem from string in InterSLIP configuration
write "+++"
pause 60
write "ath\13"
write "^4\13"
! Then go back and dial again using phone number in InterSLIP configuration
jump originate

@label 20
! Everything worked fine, you're connected now
note "Dialed successfully"
exit 0

@answer
@hangup
! Hang up the modem and reinitialize from string in InterSLIP configuration
! The only way to get here is to manually click the Disconnect button
note "Hanging up modem"
write "+++"
pause 60
write "ath\13"
write "^4\13"
exit 0


(09-Apr-96/modwdmmd/WRD)
______________________________________________________________________________
Copyright 1996  Northwest Nexus Inc.  All Rights Reserved.
This document may not be reproduced nor redistributed in any form without
express permission; contact us at support@halcyon.com with questions.